日日操夜夜添-日日操影院-日日草夜夜操-日日干干-精品一区二区三区波多野结衣-精品一区二区三区高清免费不卡

公告:魔扣目錄網為廣大站長提供免費收錄網站服務,提交前請做好本站友鏈:【 網站目錄:http://www.ylptlb.cn 】, 免友鏈快審服務(50元/站),

點擊這里在線咨詢客服
新站提交
  • 網站:51998
  • 待審:31
  • 小程序:12
  • 文章:1030137
  • 會員:747

求連續N個數據中所有連續M個數據之和的最大值。

下圖所示。

在單元格B5中,給出了一個求連續幾年薪水之和的最大值的公式。示例中是每連續4年(由單元格A5指定)薪水之和的最大值。

工作表的單元格A10中是2008年至2011年的薪水之和、B10是2009年至2012年的薪水之和,……,依此類推。其中單元格B10中的值就是所有連續4連薪水之和的最大值。

在工作表中,將單元格A5命名為“Number”。我們可以修改單元格A5中的年數,從而求出指定年數的薪水之和的最大值。

公式思路

先要獲取連續的數據。如果是4年,那么有7組連續的數據。又因為總共有10個數據,因此形成一個10行×7列的數組,在每列中需要計算的數據與該列列號對應,例如第1列是從第1個開始的4個數據,第2列是從第2個開始的4個數據。然后,將這些數據相加,形成一個有7個值的數組。最后,取出其最大值。

公式解析

單元格B5中的數組公式為:

=MAX(MMULT(A8:J8,–(ABS(TRANSPOSE(COLUMN(A8:J8))-COLUMN(OFFSET(A8:J8,0,0,1,COLUMNS(A8:J8)-Number+1))-(Number-1)/2)<Number/2)))

其中:

COLUMN(A8:J8)的值為{1,2,3,4,5,6,7,8,9,10}。

TRANSPOSE(COLUMN(A8:J8))的值為{1;2;3;4;5;6;7;8;9;10}。

也就是說,把1行10列的數組轉置為10行1列的數組。

COLUMNS(A8:J8)的值為10,由于Number是單元格A5中的值,本例中為4,因此COLUMNS(A8:J8)-Number+1的值為10-4+1,即為7。

OFFSET(A8:J8,0,0,1,COLUMNS(A8:J8)-Number+1)即為OFFSET(A8:J8,0,0,1,7),值為A8:G8。

COLUMN(OFFSET(A8:J8,0,0,1,COLUMNS(A8:J8)-Number+1))即為COLUMN(A8:G8),值為{1,2,3,4,5,6,7}。

這樣,公式:

TRANSPOSE(COLUMN(A8:J8))-COLUMN(OFFSET(A8:J8,0,0,1,COLUMNS(A8:J8)-Number+1))

變為:

{1;2;3;4;5;6;7;8;9;10}-{1,2,3,4,5,6,7}

其結果為一個10行7列的數組:

{0,-1,-2,-3,-4,-5,-6;

1,0,-1,-2,-3,-4,-5;

2,1,0,-1,-2,-3,-4;

3,2,1,0,-1,-2,-3;

4,3,2,1,0,-1,-2;

5,4,3,2,1,0,-1;

6,5,4,3,2,1,0;

7,6,5,4,3,2,1;

8,7,6,5,4,3,2;

9,8,7,6,5,4,3}

此數組再減去(Number-1)/2,本例中即(4-1)/2=1.5,得到數組:

{-1.5,-2.5,-3.5,-4.5,-5.5,-6.5,-7.5;

-0.5,-1.5,-2.5,-3.5,-4.5,-5.5,-6.5;

0.5,-0.5,-1.5,-2.5,-3.5,-4.5,-5.5;

1.5,0.5,-0.5,-1.5,-2.5,-3.5,-4.5;

2.5,1.5,0.5,-0.5,-1.5,-2.5,-3.5;

3.5,2.5,1.5,0.5,-0.5,-1.5,-2.5;

4.5,3.5,2.5,1.5,0.5,-0.5,-1.5;

5.5,4.5,3.5,2.5,1.5,0.5,-0.5;

6.5,5.5,4.5,3.5,2.5,1.5,0.5;

7.5,6.5,5.5,4.5,3.5,2.5,1.5}

然后,使用ABS函數取上面的數組的絕對值,得到數組:

{1.5,2.5,3.5,4.5,5.5,6.5,7.5;

0.5,1.5,2.5,3.5,4.5,5.5,6.5;

0.5,0.5,1.5,2.5,3.5,4.5,5.5;

1.5,0.5,0.5,1.5,2.5,3.5,4.5;

2.5,1.5,0.5,0.5,1.5,2.5,3.5;

3.5,2.5,1.5,0.5,0.5,1.5,2.5;

4.5,3.5,2.5,1.5,0.5,0.5,1.5;

5.5,4.5,3.5,2.5,1.5,0.5,0.5;

6.5,5.5,4.5,3.5,2.5,1.5,0.5;

7.5,6.5,5.5,4.5,3.5,2.5,1.5}

將上面的數組與Number/2即4/2=2比較,得到數組:

{True,False, False, False, False, False, False;

True,True, False, False, False, False, False;

True,True,True, False, False, False, False;

True,True,True,True, False, False, False;

False,True,True,True,True, False, False;

False, False, True,True,True,True, False;

False, False, False,True,True,True,True;

False, False, False, False, True,True,True;

False, False, False, False,False, True,True;

False, False, False, False,False,False,True}

前面加上雙減號(–),將True值轉換為數字1,False值轉換為0。即得到數組:

{1,0,0,0,0,0,0;

1,1, 0,0,0,0,0;

1,1,1,0,0,0,0;

1,1,1,1,0,0,0;

0,1,1,1,1,0,0;

0,0,1,1,1,1,0;

0,0,0,1,1,1,1;

0,0,0,0,1,1,1;

0,0,0,0,0,1,1;

0,0,0,0,0,0,1}

MMULT(A8:J8,上面的數組)將A8:J8形成的1行10列數組與上面獲得的10行7列數組相乘得到一個1行7列的數組:

{237348,244540,236394,228744,225739,220894,238728}

最后,使用MAX函數獲取數組中的最大值。

下面,來看看工作表第11行中的公式,例如下面是A11中的公式:

=–(COLUMNS(A8:$J$8)>=Number)

將當前單元格所在的列至列J的列數與Number值(本例中為4)比較,若大于等于Number,則為True,并使用雙減號將其轉換為數字1。

拖動A11至J11。

下面,來看看工作表第10行中的公式,例如下面是A10中的公式:

=IF(A11,SUM(A8:INDEX(A8:$J$8,1,Number)),0)

如果對應的第11行的單元格(本例為A11)中為1,那么進行求和,INDEX(A8:$J$8,1,Number)獲取當前單元格之上對應的第8行中的單元偏移Number之后的單元格。然后與當前單元格之上對應的第8行中的單元格組成要求和的單元格區域,使用SUM函數求和。

拖到A10至J10。

小結

獲得這樣一個矩陣數組真是不簡單!

建議自已輸入公式進行反復調試和體會,多練練手。

分享到:
標簽:excel公式 excel技巧 excel教程 Excel表格 Excel教程
用戶無頭像

網友整理

注冊時間:

網站:5 個   小程序:0 個  文章:12 篇

  • 51998

    網站

  • 12

    小程序

  • 1030137

    文章

  • 747

    會員

趕快注冊賬號,推廣您的網站吧!
最新入駐小程序

數獨大挑戰2018-06-03

數獨一種數學游戲,玩家需要根據9

答題星2018-06-03

您可以通過答題星輕松地創建試卷

全階人生考試2018-06-03

各種考試題,題庫,初中,高中,大學四六

運動步數有氧達人2018-06-03

記錄運動步數,積累氧氣值。還可偷

每日養生app2018-06-03

每日養生,天天健康

體育訓練成績評定2018-06-03

通用課目體育訓練成績評定